Talán ez jó lesz. Egyszerűbben sajnos nem jött össze.

Sub import()
    Dim wsTgt As Worksheet, wsSrc As Worksheet, rngTgt As Range, wbSrc As Workbook
    Dim LastEntry As String, Hit As Range
    Dim FN, Arr
   
    FN = Application.GetOpenFilename(FileFilter:="Text Files (*.txt), *.txt", Title:="Válaszd ki a barcode fájlt")
    If FN = False Then Exit Sub
    Set wbSrc = Workbooks.Open(Filename:=FN)
    Set wsSrc = wbSrc.Worksheets(1)
    Set wsTgt = ThisWorkbook.Worksheets("Munka1")
    Set rngTgt = wsTgt.Range("A" & wsTgt.Rows.Count).End(xlUp)
    If rngTgt.Value <> "" Then
        LastEntry = Replace(Format(rngTgt, "mm/dd/yy"), ".", "/") & "," & Format(rngTgt.Offset(, 1), "hh:mm:ss") & ","
        Set Hit = wsSrc.Range("A:A").Find(what:=LastEntry, LookIn:=xlValues, lookat:=xlPart)
        If Hit Is Nothing Then
            Set Hit = wsSrc.Range("A1")
        Else
            Set Hit = Hit.Offset(1)
        End If
        Set rngTgt = rngTgt.Offset(1)
    Else
        Set Hit = wsSrc.Range("A1")
    End If
    Set Hit = Range(Hit, wsSrc.Range("A" & Rows.Count).End(xlUp))
    Hit.TextToColumns DataType:=xlDelimited, Comma:=True
    Hit.Offset(, 2).Delete shift:=xlShiftToLeft
    Hit.Resize(, 3).Copy Destination:=rngTgt
    wbSrc.Close savechanges:=False
End Sub